Guardar un punto determinado de un video con Automator

Automator es una fantastica y a veces desconocida herramienta que viene incluida en las versiones de Mac OS X.

Hay veces que nos puede venir bien anotar un punto determinado de un video. Esto es muy útil en los videos de tutoriales, por ejemplo, podemos anotar los puntos más importantes o aquellos donde se explica una tarea especifica que queremos recordar para futuras pruebas o desarrollos. Otra opción seria anotar los puntos interesantes o divertidos de una pelicula, para poder tenerlos a mano rapidamente.

Existen diferentes formas de realizar esta tarea, hoy nos centraremos en una que utiliza la utilidad comentada anteriormente, Automator, junto con uno de los reproductores de video más conocidos, VLC.

Para ello vamos a crear un AppleScript en Automator, en el que iremos anotando todos los momentos interesantes de un determinado video en un archivo txt.

Abrimos Automator y elegimos la opción crear un nuevo servicio. Seleccionamos “utilidades“, y arrastramos al panel derecho “Ejecutar AppleScript“.

En el apartado, “El servicio recibe la selección de“, situado en la parte superior, seleccionamos, “sin datos de entrada“, es la última opción.

En la casilla siguiente “en” seleccionamos “otro…“, se abrira la carpeta aplicaciones, en esta carpeta seleccionamos VLC.app, obviamente tendremos que tener instalada esta aplicación.

El AppleScript es el siguiente:

on run
	set crnttime to 0
	set medianame to ""
	tell application "VLC"
		set crnttime to current time
		set mediapath to path of current item
		set medianame to get name of current item
	end tell
	set query to text returned of (display dialog "Descripción?" default answer "" buttons {"Input", "Cancel"} default button 1)
	set crnttimestring to (mediapath & ";" & crnttime & ";" & query) as string
	set this_file to ":Users:darco:Desktop:TimeFile.txt"
	my write_to_file(crnttimestring, this_file, true)
end run

on write_to_file(this_data, target_file, append_data)
	try
		set the target_file to the target_file as string
		set the open_target_file to open for access file target_file with write permission
		write this_data to the open_target_file starting at eof
		close access the open_target_file
		return true
	on error
		try
			close access file target_file
		end try
		return false
	end try
end write_to_file

Con “display dialog “Descripción?“, creamos una ventana desde la cual introducimos la “descripción” del momento del video, puedes cambiar descripción por lo que creas más oportuno.

set crnttime to current time“, nos proporciona el momento actual del video.

set mediapath to path of current item“, nos da la ruta completa del archivo que se esta reproducciendo.

set medianame to get name of current item“, nos da el nombre del video que se esta reproduciendo.

Con “set crnttimestring to (mediapath & “;” & crnttime & “;” & query) as string“, guardamos, la ruta, el momento del tiempo actual, y la descripción que hemos introducido previamente.

La instrucción “set this_file to”:Users:darco:Desktop:TimeFile.txt”“, indicamos la ruta y el nombre del archivo en el cual se guardara la información.

Guardamos el archivo de Automator creado. Localizamos el archivo y pulsamos con el cursor del ratón 2 veces solo él. Se abrira la siguiente pantalla:

Pulsamos sobre “instalar“. Si todo ha ido correctamente, ya tendremos instalado el nuevo servicio en nuestro ordenador. Ahora podemos seleccionar una combinación de teclas rápidas para llamar a nuestro servicio. Esto lo hacemos desde “Preferencias del sistema/Teclado“, seleccionamos la pestaña “Funciones rápidas” y marcamos “Servicios“. Debemos ver en el panel derecho el servicio creado, tendrá el nombre que le dimos al guardar el servicio en automator. Pulsamos en dicho servicio, donde pone “ninguna” y aquí introducimos la combinación de teclas para llamar al servicio.

Tmbien es posible invocar a nuestro servicio desde la propria aplicación VLC, en el momento que queremos capturar una nueva posición, seleccionamos en el menú “VLC/servicios“, aquí debemos ver nuestro servicio creado, solo tenemos que pulsar sobre el mismo.

En el momento de realizar una captura, si el archivo “TimeFile.txt” no existe, será creado, si existe, la anotación se realizará al final del archivo.

Al realizar una captura obtenemos lo siguiente: “/Volumes/Mac HD/Videos Musicales/Dance Monkey – Karolina Protsenko (feat. Barvina) – Tones and I – Cover-9mer-nY15Xc.mp4;118;Salto violin“.

118″ es la posición marcada del video en segundos. Los 3 datos guardados son:

  • La ruta y nombre del archivo.
  • La posición marcada, en segundos.
  • La descripción que le hemos dado.

Si se renombra el archivo .txt a .csv, podrá ser importado facilmente a una base de datos, desde la cual podemos tener un control para realizar busquedas, muy efectivo.

Share